home *** CD-ROM | disk | FTP | other *** search
/ PCMania 73 / PCMania CD73_1.iso / pcmania / render73 / Foro / CASAS / POSTURAS.INC < prev    next >
Text File  |  1997-03-29  |  5KB  |  152 lines
  1.  
  2. //Se definen las texturas del mech
  3.  
  4. #declare tmech = texture{
  5.  pigment{
  6.    wrinkles
  7.    color_map{ [0 Gold] [0.5 Gold] [0.5 Brown] [1 Brown]}
  8.  }
  9.  
  10.  finish{
  11.   specular 0.7
  12.   brilliance 15
  13.   metallic
  14.  }
  15.  scale<7,7,7>
  16.  }
  17.  
  18.  #declare cristal= texture{
  19.   pigment{rgbf<0.7,0.7,1,0.5>}
  20.   finish{specular 0.9 reflection 1}
  21.  }
  22.  
  23.  
  24. //En estas lφneas se declaran los nombres de las diferentes partes del mech
  25.  
  26. #declare cadera=object{#include "mech22.inc" texture{tmech}}          //La cadera
  27. #declare cannon= object{#include "mech1.inc" texture{tmech}}          //El ca±≤n
  28. #declare dedo3= object{#include "mech2.inc" texture{tmech}}           //Un dedo
  29. #declare dedo2= object{#include "mech3.inc" texture{tmech}}           //Otro
  30. #declare dedo1= object{#include "mech4.inc" texture{tmech}}           //Otro
  31. #declare anteb_iz= object{#include "mech5.inc" texture{tmech}}        //Antebrazo izquierdo
  32. #declare muslo_der=object{#include "mech6.inc" texture{tmech}}        //Muslo derecho
  33. #declare muslo_iz=object{#include "mech7.inc" texture{tmech}}         // "    izdo.
  34. #declare pierna_der=object{#include "mech8.inc" texture{tmech}}       //Pierna drcha.
  35. #declare pierna_iz=object{#include "mech9.inc" texture{tmech}}        //  "     iz.
  36. #declare hombro_iz=object{#include "mech10.inc" texture{tmech}}       // Hombro iz.
  37. #declare hombro_der=object{#include "mech11.inc" texture{tmech}}      //   "    drcho.
  38. #declare pie_iz=object{#include "mech12.inc" texture{tmech}}          //Pie iz.
  39. #declare pie_der=object{#include "mech13.inc"texture{tmech}}         //Pie drcho.
  40. #declare pectoral=object{
  41.  union{
  42.    object{#include "mech20.inc"}                       //Pectoral
  43.    object{#include "mech19.inc"}                       //Misil iz.
  44.    object{#include "mech21.inc"}                       //  "   drcho.
  45.  }
  46.  texture{tmech}
  47. }
  48.  
  49. #declare cabina= object{
  50.  union{
  51.    object{#include "mech24.inc" texture{tmech}}               //El habitßculo de la cabina
  52.    object{#include "mech23.inc" texture{cristal}}             //El cristal
  53.    object{#include "mech14.inc" pigment{rgb<0.8,0.3,0.3>}}    //La cabeza del piloto
  54.    object{#include "mech15.inc" pigment{rgb<0.6,0.6,0.6>}}    //El cuerpo del piloto
  55.    object{#include "mech16.inc" pigment{rgb<0.8,0.8,0.8>}}    //El panel de mandos izquierdo
  56.    object{#include "mech17.inc" pigment{rgb<0.8,0.8,0.8>}}    //El panel de mandos derecho
  57.    object{#include "mech18.inc" pigment{rgb<1,1,0>}}          //El asiento
  58.  }
  59. }
  60.  
  61.  
  62.  
  63. //Ahora se definen las jerarquφas, el eje local (punto de pivotaje) y la rotaci≤n de
  64. //cada parte del mech seg·n las variables declaradas antes
  65.  
  66. #declare mech= object{
  67. union{
  68. union{
  69.  object{pectoral}
  70.  //Brazo izquierdo. . . . . .
  71.  union{
  72.    object{hombro_iz}
  73.    union{
  74.      object{anteb_iz}
  75.      union{
  76.       object{dedo1 translate<-158,-134,40> rotate<rdedo1x,rdedo1y,rdedo1z> translate<158,134,-40>}
  77.       object{dedo2 translate<-159,-134,40> rotate<rdedo2x,rdedo2y,rdedo2z> translate<154,134,-40>}
  78.       object{dedo3 translate<-158,-134,40> rotate<rdedo3x,rdedo3y,rdedo3z> translate<158,134,-40>}
  79.      }
  80.    translate<-154,-212,-24>
  81.    rotate<ranteb_izx,ranteb_izy,ranteb_izz>
  82.    translate<154,212,24>
  83.    }
  84.  translate<-154,-287,11>
  85.  rotate<rhombro_izx,rhombro_izy,rhombro_izz>
  86.  translate<154,287,-11>
  87.  }
  88.  //Brazo derecho . . . . .
  89.  union{
  90.    object{hombro_der}
  91.    object{cannon translate<154,-210,15> rotate<rcannonx,rcannony,rcannonz> translate<-154,210,-15>}
  92.  translate<132,-283,11>
  93.  rotate<rhombro_derx,rhombro_dery,rhombro_derz>
  94.  translate<-132,283,-11>
  95.  }
  96.  //Cabeza
  97.  object{cabina translate<-0,-308,-0> rotate<rcabinax,rcabinay,rcabinaz> translate<0,308,0>}
  98. translate<-8,-265,-9>
  99. rotate<rpectoralx,rpectoraly,rpectoralz>
  100. translate<8,265,11>
  101. }
  102.  
  103.  //Parte inferior del mech . . .
  104.  
  105. union{
  106.   object{cadera}
  107.   union{
  108.     object{muslo_iz}
  109.     union{
  110.       object{pierna_iz}
  111.       object{
  112.         pie_iz
  113.         translate<-91,-42,80>
  114.         rotate<rpie_izx,rpie_izy,rpie_izz>
  115.         translate<91,42,-80>
  116.       }
  117.     translate<-92,-136,-76>
  118.     rotate<rpierna_izx,rpierna_izy,rpierna_izz>
  119.     translate<92,136,76>
  120.     }
  121.   translate<-95,-192,17>
  122.   rotate<rmuslo_izx,rmuslo_izy,rmuslo_izz>
  123.   translate<95,192,17>
  124.   }
  125.  
  126.   union{
  127.     object{muslo_der}
  128.     union{
  129.       object{pierna_der}
  130.       object{
  131.         pie_der
  132.         translate<81,-46,-50>
  133.         rotate<rmuslo_derx,rmuslo_dery,rmuslo_derz>
  134.         translate<-81,46,50>
  135.       }
  136.     translate<79,-136,-76>
  137.     rotate<rpierna_derx,rpierna_dery,rpierna_derz>
  138.     translate<-79,136,76>
  139.     }
  140.   translate<74,-186,17>
  141.   rotate<rmuslo_derx,rmuslo_dery,rmuslo_derz>
  142.   translate<-74,186,-17>
  143.   }
  144.  
  145. translate<-10,-187,-9>
  146. rotate<rcaderax,rcaderay,rcaderaz>
  147. translate<10,187,9>
  148. }
  149. }
  150. translate<0,-30,0>
  151. }
  152.